// This file was decompiled using sascm.ini published by Seemann (http://sannybuilder.com/files/SASCM.rar) on 04.08.2007

{$VERSION 3.1.0023}
{$CLEO .cs}

//-------------MAIN---------------
thread 'KNIFE' 

:KNIFE_10
0001: wait 0 ms
00D6: if                       
02D8:   actor $PLAYER_ACTOR current_weapon == 4 
004D: jump_if_false @KNIFE_10
if 
00E1:   player 0 pressed_key 6 // aim 
then
jump @KNIFE_20
end
0006: 29@ = 0
0164: disable_marker 30@ 
jump @KNIFE_10

:KNIFE_20
0006: 31@ = 0
for 1@ = 0 to 35584 step 256
0085: 0@ = 1@ // (int)
    for 2@ = 0 to 127
        if 
        056D:   actor 0@ defined 
        then
            if and
            803C:   not  $PLAYER_ACTOR == 0@ // (int) 
            80DF:   not actor 0@ driving 
            8118:   not actor 0@ dead 
            then
            gosub @NEAR_ACTOR
            end
        end
    000A: 0@ += 1
    end
end
if
056D:   actor 31@ defined 
then
    if
    803B:   not  29@ == 31@ // (int) 
    then
    0164: disable_marker 30@ 
    0187: 30@ = create_marker_above_actor 31@ 
    0085: 29@ = 31@ // (int)
    end
    if
    00E1:   player 0 pressed_key 17 // fire
    then
    04ED: load_animation "KNIFE"
    while 84EE:   not animation "KNIFE" loaded 
    0001: wait 0 ms 
    end
    jump @KNIFE_30
    end
end
jump @KNIFE_10

:KNIFE_30
0006: 29@ = 0
0164: disable_marker 30@
068D: get_camera_position_to 0@ 1@ 2@ 
015F: set_camera_position 0@ 1@ 2@ rotation 0.0 0.0 0.0 
068E: get_camera_target_point_to 0@ 1@ 2@
0160: set_camera_point_at 0@ 1@ 2@ mode 2  
02AB: set_actor $PLAYER_ACTOR immunities BP 1 FP 1 EP 1 CP 1 MP 1
04D7: toggle_actor 31@ locked 1
04C4: store_coords_to 0@ 1@ 2@ from_actor 31@ with_offset 0.0 -1.0 0.0 
0972: put_actor $PLAYER_ACTOR at 0@ 1@ 2@ // versionC 
0172: 0@ = actor 31@ Z_angle 
0173: set_actor $PLAYER_ACTOR Z_angle_to 0@
04C4: store_coords_to 0@ 1@ 2@ from_actor 31@ with_offset 0.0 1.0 0.0
0668: AS_actor 31@ rotate_and_shoot_at 0@ 1@ 2@ 5000 ms 
0812: AS_actor $PLAYER_ACTOR perform_animation "KILL_Partial" IFP_file "KNIFE" 4.0 loopA 1 lockX 0 lockY 0 lockF 0 time 500 // versionB
0001: wait 500 ms 
02EB: restore_camera_with_jumpcut 
0812: AS_actor $PLAYER_ACTOR perform_animation "KILL_Knife_Player" IFP_file "KNIFE" 1.0 loopA 1 lockX 0 lockY 0 lockF 0 time 2300 // versionB
0001: wait 350 ms  
0812: AS_actor 31@ perform_animation "KILL_Knife_Ped_Damage" IFP_file "KNIFE" 1.0 loopA 1 lockX 0 lockY 0 lockF 0 time 2000 // versionB
00A0: store_actor 31@ position_to 0@ 1@ 2@
0001: wait 1000 ms 
09B8: create_blood_gush_at 0@ 1@ 2@ with_offset 0.0 0.0 3.0 density 500 on_actor 31@
0001: wait 1000 ms 
0829: actor 31@ perform_animation "KILL_Knife_Ped_Die" IFP_file "KNIFE" 4.0 time 0 and_dies
04D7: toggle_actor 31@ locked 0  
01B4: toggle_player $PLAYER_CHAR can_move 1
jump @KNIFE_10

:NEAR_ACTOR
if
056D:   actor 31@ defined
then
068E: get_camera_target_point_to 3@ 4@ 5@
068D: get_camera_position_to 6@ 7@ 8@
000F: 8@ -= 0.1
0063: 3@ -= 6@ // (float) 
0063: 4@ -= 7@ // (float) 
0063: 5@ -= 8@ // (float) 
0013: 3@ *= 150.0 
0013: 4@ *= 150.0 
0013: 5@ *= 150.0 
00A0: store_actor $PLAYER_ACTOR position_to 6@ 7@ 8@
005B: 3@ += 6@ // (float) 
005B: 4@ += 7@ // (float) 
005B: 5@ += 8@ // (float) 
00A0: store_actor 31@ position_to 9@ 10@ 11@
050A: 12@ = distance_between_XYZ 3@ 4@ 5@ and_XYZ 9@ 10@ 11@
050A: 13@ = distance_between_XYZ 6@ 7@ 8@ and_XYZ 9@ 10@ 11@
005B: 12@ += 13@ // (float)
00A0: store_actor 0@ position_to 9@ 10@ 11@
050A: 13@ = distance_between_XYZ 3@ 4@ 5@ and_XYZ 9@ 10@ 11@
050A: 11@ = distance_between_XYZ 6@ 7@ 8@ and_XYZ 9@ 10@ 11@
005B: 13@ += 11@ // (float) 
    if 
    0025:   12@ > 13@ // (float)
    then 
    0085: 31@ = 0@ // (int)
    end
else
0085: 31@ = 0@ // (int)
end
return