knife

総資産

円

knife.csのソース解説

---スクリプトの説明---
　このcsでは、ナイフを選択している状態でaimを押すと、見ているところに一番近い人(CJと死んでいる人と乗り物に乗っている人は除く)を探し、その人を攻撃対象にしてマーカーをつけます。(aimを離すとマーカーも削除)
攻撃対象が存在する状態でfireを押すと、少しの間カメラを固定して、対象の後ろにワープして、首を切る動作をし、対象を殺します。

---ソースファイル---
　knife.txt

---解説---

// This file was decompiled using sascm.ini published by Seemann (http://sannybuilder.com/files/SASCM.rar) on 04.08.2007

{$VERSION 3.1.0023}
{$CLEO .cs}

//-------------MAIN---------------
thread 'KNIFE'

:KNIFE_10
0001: wait 0 ms
00D6: if                       
02D8:   actor $PLAYER_ACTOR current_weapon == 4 
//ナイフを選択しているか。武器番号はヘルプの"SCM Documentation\GTA SA\Weapon numbers"を参照。
004D: jump_if_false @KNIFE_10
//違うならKNIFE_10へ飛ぶ。
if 
00E1:   player 0 pressed_key 6 // aim
//aimを押しているか。キー番号はヘルプの"SCM Documentation\GTA SA\Keypress numbers"を参照。
then 
//しているなら
jump @KNIFE_20 
//KNIFE_20へ飛ぶ。
end 
//していないなら何も行わずにif文が終了。
0006: 29@ = 0
//29@の初期化
0164: disable_marker 30@ 
//マーカー30@を削除。つまりaimしていない場合マーカー30@は表示されない。
jump @KNIFE_10

:KNIFE_20
0006: 31@ = 0 
//ターゲットのアクター用の変数を初期化。
//存在する人を0@に割り当てる処理。
for 1@ = 0 to 35584 step 256 
//for文。1@が256刻みで増えていき、35584になるまでfor内の処理を繰り返す。
0085: 0@ = 1@ // (int) 
//これらのfor文で全ての人に変数を割り当てることができます。
    for 2@ = 0 to 127 
    //詳しくはばりすたん家さんのcleo3wikiで。
        if 
        056D:   actor 0@ defined 
        //アクター0@が定義されているか。
        then 
        //されているなら
            if and 
            //以下の条件が全て真か。
            803C:   not  $PLAYER_ACTOR == 0@ // (int) 
            //0@がCJではなくて、
            80DF:   not actor 0@ driving 
            //0@が車に乗っていなくて、
            8118:   not actor 0@ dead 
            //0@が死んでいないか
            then 
            //そうなら
            gosub @NEAR_ACTOR 
            //サブルーチンの@NEAR_ACTOR(一番下にある)へ飛ぶ。
            //(見ているところに近い人を31@に割り当てるサブルーチン)
            end
        end
    000A: 0@ += 1
    end
end
//存在する人を0@に割り当てる処理終わり。
if
056D:   actor 31@ defined 
//アクター31@(ターゲット)が定義されているか。
then
    if 
    //ここではアクター31@が別の人に変わった場合の処理を行う。
    803B:   not  29@ == 31@ // (int) 
    //31@と29@が等しくないか。最初は29@に値は代入されていないので成り立つ。
    //そしてthen以降が実行されると29@に31@が代入されるので次からは成り立たなくなる。
    //しかしターゲットが変わる(つまり31@の値が変わる)とまた成り立ち、
    //前のターゲットについていたマーカーを消し、新しいターゲットにマーカーを付ける。
    then
    0164: disable_marker 30@ 
    //マーカー30@削除。
    0187: 30@ = create_marker_above_actor 31@ 
    //アクター31@にマーカー30@を作成。
    0085: 29@ = 31@ // (int) 
    //29@に31@を代入
    end
    if
    00E1:   player 0 pressed_key 17 // fire 
    //fireが押されたか
    then
    04ED: load_animation "KNIFE"
    //アニメーションの"KNIFE"を読み込む。
    while 84EE:   not animation "KNIFE" loaded 
    //読み込めてない間はwait0msを実行。
    0001: wait 0 ms 
    end 
    //読み込みが終わるとwhileを抜け出しKNIFE_30へ飛ぶ。
    jump @KNIFE_30
    end
end
//31@が定義されてなかったりfireが押されていない場合KNIFE_10へ飛ぶ。
jump @KNIFE_10

:KNIFE_30
0006: 29@ = 0 
//29@の値を初期化
0164: disable_marker 30@
068D: get_camera_position_to 0@ 1@ 2@ 
//カメラのポジションを取得して
015F: set_camera_position 0@ 1@ 2@ rotation 0.0 0.0 0.0 
//そこに固定。
068E: get_camera_target_point_to 0@ 1@ 2@ 
//カメラのターゲットポジションを取得して
0160: set_camera_point_at 0@ 1@ 2@ mode 2 
//そこに固定。
02AB: set_actor $PLAYER_ACTOR immunities BP 1 FP 1 EP 1 CP 1 MP 1 
//CJに全ての耐性がつく。それぞれ、銃撃、炎、爆発、(多分)衝撃、不明。
04D7: toggle_actor 31@ locked 1 
//31@を移動できなくする。
04C4: store_coords_to 0@ 1@ 2@ from_actor 31@ with_offset 0.0 -1.0 0.0 
//31@の1m後ろの座標取得。
0972: put_actor $PLAYER_ACTOR at 0@ 1@ 2@ // versionC 
//そこにCJの移動。普通のput_actorは移動後に少し上に浮くがversionCではそうならない。
0172: 0@ = actor 31@ Z_angle 
//31@のZ軸の向きを取得。つまり左右の向き。
0173: set_actor $PLAYER_ACTOR Z_angle_to 0@ 
//CJの向きをその向きに。
04C4: store_coords_to 0@ 1@ 2@ from_actor 31@ with_offset 0.0 1.0 0.0 
//31@の1m前の座標取得。
0668: AS_actor 31@ rotate_and_shoot_at 0@ 1@ 2@ 5000 ms 
//31@を5秒間その場所に向かせ銃撃させる。
0812: AS_actor $PLAYER_ACTOR perform_animation "KILL_Partial" IFP_file "KNIFE" 4.0 loopA 1 lockX 0 lockY 0 lockF 0 time 500 // versionB
//CJにknife.ifp内のKILL_Partialのアニメーションをさせる。
0001: wait 500 ms 
//そのアニメーションの待ち時間。
02EB: restore_camera_with_jumpcut 
//固定したカメラをすぐに元に戻す。
0812: AS_actor $PLAYER_ACTOR perform_animation "KILL_Knife_Player" IFP_file "KNIFE" 1.0 loopA 1 lockX 0 lockY 0 lockF 0 time 2300 // versionB
0001: wait 350 ms  
0812: AS_actor 31@ perform_animation "KILL_Knife_Ped_Damage" IFP_file "KNIFE" 1.0 loopA 1 lockX 0 lockY 0 lockF 0 time 2000 // versionB
00A0: store_actor 31@ position_to 0@ 1@ 2@
0001: wait 1000 ms 
09B8: create_blood_gush_at 0@ 1@ 2@ with_offset 0.0 0.0 3.0 density 500 on_actor 31@ 
//噴出する血作成。
0001: wait 1000 ms 
0829: actor 31@ perform_animation "KILL_Knife_Ped_Die" IFP_file "KNIFE" 4.0 time 0 and_dies
04D7: toggle_actor 31@ locked 0  
01B4: toggle_player $PLAYER_CHAR can_move 1 
//これを行うと耐性が元に戻るようです。
jump @KNIFE_10

:NEAR_ACTOR
if
056D:   actor 31@ defined 
//アクター31@(ターゲット)が定義されているかどうか。
then 
//二回目以降は31@が定義されているのでここの処理が行われる。
068E: get_camera_target_point_to 3@ 4@ 5@
//カメラのターゲットポジション取得。(カメラの見ている場所。
//見ている場所なので凄く遠くにあると思うかもしれませんが、
//実はカメラポジションのすぐ近くにあります。)
068D: get_camera_position_to 6@ 7@ 8@ 
//カメラのポジション取得。(これも)
000F: 8@ -= 0.1 
//なんとなく0.1引く。
0063: 3@ -= 6@ // (float) 
0063: 4@ -= 7@ // (float) 
0063: 5@ -= 8@ // (float) 
//これらの引き算でカメラのポジションからのカメラのターゲットポジションの座標を取得できる。
//つまりローカル座標とかいうやつ。
0013: 3@ *= 150.0 
//さっき書いたようにターゲットポジションとポジションは近いのでローカル座標は値が小さいです。
0013: 4@ *= 150.0 
//なので150倍します。 
0013: 5@ *= 150.0 
//これで多分距離が100mくらいになると思います。(多分
00A0: store_actor $PLAYER_ACTOR position_to 6@ 7@ 8@ 
//CJの座標取得。
005B: 3@ += 6@ // (float) 
005B: 4@ += 7@ // (float) 
005B: 5@ += 8@ // (float) 
//CJの座標とさっき求めたローカル座標を足す。これで見ている場所の100m程度先の座標を取得できます。
00A0: store_actor 31@ position_to 9@ 10@ 11@ 
//31@の座標取得
050A: 12@ = distance_between_XYZ 3@ 4@ 5@ and_XYZ 9@ 10@ 11@ 
//見ている場所と31@の間の距離取得。
050A: 13@ = distance_between_XYZ 6@ 7@ 8@ and_XYZ 9@ 10@ 11@
//CJと31@の間の距離取得。
005B: 12@ += 13@ // (float) 
//この12@はCJと見ている場所の間の直線上にあるとき一番小さくなるはずです。
00A0: store_actor 0@ position_to 9@ 10@ 11@
050A: 13@ = distance_between_XYZ 3@ 4@ 5@ and_XYZ 9@ 10@ 11@
050A: 11@ = distance_between_XYZ 6@ 7@ 8@ and_XYZ 9@ 10@ 11@
005B: 13@ += 11@ // (float) 
//13@も12@と同様にCJと見ている場所の間の直線上にあるとき小さくなり、
//その直線から離れれば離れるほど大きくなります。
    if 
    0025:   12@ > 13@ // (float) 
    //つまりその直線上から31@が0@より離れているかどうか。
    then 
    0085: 31@ = 0@ // (int) 
    //そうなら0@を31@とする。これで一番近い人を見つけることができるはずです。
    end
else 
//最初は31@は定義されてないのでここの処理が行われる
0085: 31@ = 0@ // (int) 
//31@に0@を代入
end
return 
// 元の場所へ戻る。つまりgosub @NEAR_ACTORのところ。

・2008/07/06

を
に訂正。

戻る

 トップ